ASP 类专题

2016-02-19 09:43 6 1 收藏

关注图老师设计创意栏目可以让大家能更好的了解电脑,知道有关于电脑的更多有趣教程,今天给大家分享ASP 类专题教程,希望对大家能有一点小小的帮助。

【 tulaoshi.com - Web开发 】

严格地说,ASP 并不是一门编程语言,所以不存在类这一概念,我们这里说 ASP 类是指 ASP 的编程语言 VBScript 在 ASP 里应用时的类。
ASP 类比较简单,它不具有真正意义类的继承、重载等特性,尽管如此,它仍然是非常有用的,它降低了我们编程的复杂度,使我们的程序模块更加合理。
ASP 类支持什么 ASP 类比较简单,它不具有真正意义类的继承、重载等特性。它支持以下内容: 
公有成员变量、私有成员变量、属性 
公有成员函数、私有成员函数 
构造函数、析构函数 
创建和使用一个最简单的 ASP 类 一些初学者不理解类和对象的区别,打个比方,类好比是图纸,对象好比是根据图纸制作出的实物。 该示例给出了 ASP 类及对象的简单示例,该类仅含有一个成员函数,用以解释类的基本格式,并给出创建、释放对象的方法。 详细内容 ASP 类成员变量、成员函数、构造析构函数 这是一个比较完整的类讲解,所有的讲解都有注释的方式写在程序的旁边。 通过阅读本节,对 ASP 类有一个较为全面的理解,可以进行 ASP 类模块的开发。 详细内容 ASP 类属性 ASP 类属性与 ASP 类公有成员变量相比具有以下一些特点。 
可以在赋值的同时执行其它功能 
可以确定赋值范围 
可以将设定只读、只写属性 
所以 ASP 类属性也是比较常用且重要的。 详细内容 ASP 类组合 ASP 类的功能实在有限,所以有时我们要实现复杂的功能,只好用组合来实现。 
创建一个最简单的 ASP 类
class CFoo
    sub PrintHello()
        response.Write "Hello World!"
    end sub
end class

可以看出,ASP 类的基本结构是:
class 类名
    类代码
end class

使用一个最简单的 ASP 类
dim obj
set obj = new CFoo '使用 set new 创建对象,由于不是服务器组件,所以不能用 server.CreateObject 创建
call obj.PrintHello '对象名称后加点,再跟成员变量、属性或函数,表示调用该对象的成员变量、属性或函数,将显示 Hello World!
set obj = nothing '释放对象

ASP 类里不能重载构造函数,所以我们不能使用类似于 set obj = new CFoo("param") 的语句来创建类。
ASP 类的功能实在有限,所以有时我们要实现复杂的功能,只好用组合来实现。
class CFish
    sub Swim()
    end sub
end class
class CBird
    sub Fly()
    end sub
end class
class CAnimal
    dim fish
    dim bird
    private sub class_initialize()
        set fish = new CFish
        set bird = new CBird
    end sub

    private sub class_terminate()
        set fish = nothing
        set bird = nothing
    end sub
end class
dim animal
set animal = new CAnimal
call animal.fish.Swim() '鱼游
call animal.bird.Fly() '鸟飞
set animal = nothing
ASP 类属性
class CFoo
    private pvt

    '属性写
    public property let propName(v)
        pvt = v
    end property

    '属性读
    public property get propName()
        PropName = pvt
    end property
end class

dim obj
set obj = new CFoo
obj.propName = "属性值"
response.Write(obj.propName) '显示“属性值”
set obj = nothing

可以看出属性值相当于是在私有成员变量与外界之间架了一座桥梁,使双方可以互相通信。
有人就会问属性跟公有成员变量一样,它的存在又有什么独立的意义呢?
1、可以在赋值的同时执行其它功能
如下代码,相当于同时为两个成员变量赋值
    public property let propName(v)
        pvt = v
        另一个私有成员变量名 = "pvt 的值:" & v
    end property
2、可以确定赋值范围
假如上例中的属性写改为如下:
    public property let propName(v)
        if Len(v) = 5 then
            pvt = v
        end if
    end property
执行 obj.propName = "个十百千万亿" 将不会为 pvt 赋值成功,因为该字符串的长度超过了 5。
3、可以将设定只读、只写属性
如上例中,假如我们将 let 函数去掉,调用 obj.propName = "属性值" 就会出错,因为这时候函数只可读。
class CFoo
    dim publicParam '用 dim 申明公有成员变量
    private privateParam '用 private 申明私有成员变量
    'publicParam = "公有" '不能在 class 标记以内、类函数以外为成员变量赋值
    'const MAX_LEN = 5 '不能在 class 标记以内、类函数以外使用 const

    '该函数为构造函数,在使用 set new 创建对象时,自动执行
    private sub class_initialize()
        publicParam = "公有" '可以在这里为成员变量赋值
        privateParam = "私有"
    end sub

    '该函数为析构函数,在使用 set nothing 释放对象时,自动执行
    private sub class_terminate()
        response.Write "释放对象"
    end sub

    '公有成员函数(过程)
    '成员函数(过程)不需要也不能申明
    sub PrintParam(index)
        if index = 1 then
            call PrintPublicParam()
        elseif index = 2 then
            call PrintPrivateParam()
        end if
    end sub

    '私有成员函数(过程)
    '只是比公有成员函数(过程)多一个 private
    private sub PrintPublicParam()
        response.Write publicParam
    end sub

    private sub PrintPrivateParam()
        response.Write privateParam
    end sub
end class

dim obj
set obj = new CFoo '自动调用 class_initialize 函数,为 publicParam、privateParam 赋值
obj.publicParam = "新的公有"
obj.privateParam = "新的私有" '将发生错误,因为 privateParam 是私有变量
call obj.PrintParam(1) '显示 publicParam 的值
call obj.PrintPublicParam() '将发生错误,因为 PrintPublicParam 是私有函数
set obj = nothing '自动调用 class_terminate 函数,显示“释放对象”

来源:https://www.tulaoshi.com/n/20160219/1591862.html

延伸阅读
标签: Web开发
作者的blog: http://blog.csdn.net/oyiboy/ 我之所以还是要宣扬用MVC来开发ASP,只是想让面向过程的思考方式变成面向对象的思考方式,这个对于任何一种语言的开发员来说都是有好处的。 MVC是个标准模型,ASP要实现似乎真的是很困难,但是标准是标准,运用是运用,既然ASP要实现这个模型很难,那可以尝试着将MVC模型变形成适合自己的模型...
标签: Web开发
所有写程序的人都知道,当你逐渐对您要实现的功能展开的时候,很大的时候,第一天写的东西第二天就忘了写到那里了,很多的时候,不得不写上详细的程序开发笔记,这在ASP的系统开发中感觉尤其文件、函数复杂的时候,当我们打算对网站的一部分功能进行修改的时候,感觉无从下手或者感觉要修改的地方。这时候,如果您学过任何一门面向对象的编程的...
标签: ASP
  方式一:把Java类注册成ActiveX组件 步骤一: 创建一个Java类,命名为Test.java public class Test {       public String getWord()       {           return "Hello World";       } } 步骤二: 编译成c...
标签: ASP
class Base64Class rem Const dim sBASE_64_CHARACTERS'转化码 dim lenString '计算字符串的长度 dim iCount '计数器 dim returnValue '返回值 dim tempChar'缓存字符 dim tempString'缓存字符串 dim paramString '参数字符串 dim temHex'缓存缓存十六进制 dim tempLow'缓存低位 dim tem...
标签: Web开发
前几天大佛写了“ASP设计模式”,可能有些初学者或者刚刚接触ASP的朋友不一定完全看得明白,偶就整理了一下编写一个ASP类的方法,大部分是从网上找来的。希望对朋友们有帮助。  《ASP设计模式》(作者 我佛山人): dispbbs.asp?boardID=20&ID=247879 首先ASP的类是由事件和方法(它们就是构成类的成员了)构成的,如果大家还没有接...

经验教程

162

收藏

25
微博分享 QQ分享 QQ空间 手机页面 收藏网站 回到头部